Rif: AW: Triggering event for MIGO

[Angelo Besenzoni]

Thanks Stephan,
 
Output Message Control is a great idea for triggering event creation of material
document.
 
Unfortunately, on my system the output control doesn't run with medium 9
(because in the routine RVNSWE01 the search of the Event is in table NAST but
the event is in table NACH... i don't know why. )....
So, i had created an Output Message with medium 8 (special function) with the
following routine:
 
 
**********************************************************************************************************************
report zsfx003 .
include <cntn01>.
tables: nast.
 
*---------------------------------------------------------------------*
*       form create_event
*
*---------------------------------------------------------------------*
*       create_event is called by output control
*
*---------------------------------------------------------------------*
form create_event using returncode like sy-subrc
                        us_screen  type c.
 
  data: l_objkey like sweinstcou-objkey,
        l_creator like swhactor,
        l_msgv1 like sy-msgv1,
        l_msgv2 like sy-msgv2,
        l_eventid like swedumevid-evtid,
* the next line defines the object TYPE that will be used
        l_objtype like swetypecou-objtype value 'MSEG',
 
* the next line defines the event to be created
        l_event like swetypecou-event value 'GRCreated'.
 
* no preview available
  check us_screen eq space.
 
* use NAST object key -- you might need to change this
* if your event is based on a completely different object
  l_objkey = nast-objky.
 
  l_creator-otype = 'US'.
  l_creator-objid = sy-uname.
 
  call function 'SWE_EVENT_CREATE'
       exporting
            objtype  = l_objtype
            objkey   = l_objkey
            event    = l_event
            creator  = l_creator
       importing
            event_id = l_eventid
       exceptions
            others   = 1.
 
  if sy-subrc <> 0.
* event could not be created
    l_msgv1 = l_event.
    l_msgv2 = l_objtype.
    call function 'NAST_PROTOCOL_UPDATE'
         exporting
              msg_arbgb = 'VN'
              msg_nr    = '075'
              msg_ty    = 'E'
              msg_v1    = l_msgv1
              msg_v2    = l_msgv2.
    returncode = 4.
  else.
* creation was ok
    returncode = 0.
  endif.
endform.
 
**********************************************************************************************************************************************
 
it seems correctly running  ............
 
bye...
Angelo
 
Angelo Besenzoni
Sap Italia Consulting s.r.l.
tel. +39 3351357236
 
 
 
|--------+------------------------------------>
|        |          "Becker Stephan (extern)" |
|        |          <Stephan.Becker.ext at mchw.s|
|        |          iemens.de>                |
|        |                                    |
|        |          01/08/2002 10.47          |
|        |          Per favore, rispondere a  |
|        |          SAP Workflow Users' Group |
|        |                                    |
|--------+------------------------------------>
  >----------------------------------------------------------------------------|
  |                                                                            |
  |       Per:    SAP-WUG at MITVMA.MIT.EDU                                       |
  |       Cc:     (ccr: Angelo Besenzoni/SAP_CONSULTING)                       |
  |       Oggetto:     AW: Triggering event for MIGO                           |
  >----------------------------------------------------------------------------|
 
 
 
 
 
 
Hi Angelo,
 
try triggering the event using standard means, in this case output control.
Here's a little excerpt from one of my postings a little while back:
 
...
 
use output control to create the event. Each user who creates MIGO documents
must have user parameter NDR set to "X" (don't ask!), and then it works.
 
In transaction NACE, Application ME, create a new output type with Partner
Function Events (workflow) and processing routine RVNSWE01, form
CREATE_EVENT.
 
Then enter condition records for the key combination you need (the MM
consultant should now these), Medium 9, Timing 4. In the communication
settings (pushbutton from the condition maintenance), you specify the event
you want.
 
Also add the output type to procedure ME0001.
 
Hth,
Stephan
 
 
-----Urspr
-------------- next part --------------
=FCngliche Nachricht-----
Von: Angelo Besenzoni [mailto:"Angelo
Besenzoni/SAP_CONSULTING%SAP_CONSULTING"@jaguar.ibm.it]
Gesendet: Donnerstag, 1. August 2002 11:46
An: SAP-WUG at MITVMA.MIT.EDU
Betreff: Triggering event for MIGO
 
 
Hi everyone...
 
I have a problem in triggering event for GR creation by MIGO.
 
With transactions MB01, MB31,... i can use user-exit MB_CF001...
 
But with MIGO there does not appear to be a user exit and no event occu=
rs
when a
save occurs (no change documents are linked to this)
 
Hopefully someone has ecountered similar problem and point me in the ri=
ght
direction.
 
Thanks for all.
 
Regards.
Angelo.
 
 
Angelo Besenzoni
Sap Italia Consulting s.r.l.
tel. +39 3351357236
 
=